Arduino Audio Tools: Using FTP as Data Source

I published a new release of my TinyFTP library, that I have converted to a header only C++ library and I changed the FTPClient to a templated class so that we can support an automatic session management with different Client implementations.

I already provided an simple ftp example in the AudioTools library that just uses an individual FTP File as data source.

However, I thought it would be cool to have a FTP audio source for the AudioPlayer!

Example Arduino Sketch

Here is a simple example sketch the uses the ESP32 AI Thinker AudioKit as output device and we can use the buttons for navigating between the files. The data is loaded from a FTP Server!

#include "WiFi.h"
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"
#include "AudioTools/AudioLibs/AudioBoardStream.h"
#include "AudioTools/Disk/AudioSourceFTP.h"

const char* path = "Music/Tracy Chapman/Matters of the Heart";
const char* ext = "mp3";
const char* ftp_user = "user";
const char* ftp_pwd = "pwd";
const char* ssid = "ssid";
const char* ssid_pwd = "ssid pwd";

FTPClient<WiFiClient> ftp;
AudioSourceFTP<WiFiClient> source(ftp, path, ext);
AudioBoardStream i2s(AudioKitEs8388V1);
MP3DecoderHelix decoder; 
AudioPlayer player(source, i2s, decoder);

void next(bool, int, void*) { player.next(); }

void previous(bool, int, void*) { player.previous(); }

void startStop(bool, int, void*) { player.setActive(!player.isActive()); }

void setup() {
  Serial.begin(115200);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
  FTPLogger::setOutput(Serial);
  //FTPLogger::setLogLevel(LOG_DEBUG);

  // connect to WIFI
  WiFi.begin(ssid, ssid_pwd);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();
  WiFi.setSleep(false);

  // connect to ftp
  if (!ftp.begin(IPAddress(192,168,1,39), ftp_user, ftp_pwd)){
    Serial.println("ftp failed");
    stop();
  }

  // setup output
  auto cfg = i2s.defaultConfig(TX_MODE);
  if (!i2s.begin(cfg)){
    Serial.println("i2s failed");
    stop();
  }

  // setup additional buttons
  i2s.addDefaultActions();
  i2s.addAction(i2s.getKey(1), startStop);
  i2s.addAction(i2s.getKey(4), next);
  i2s.addAction(i2s.getKey(3), previous);

  // setup player
  player.setVolume(0.7);
  // load the directory 
  if (!player.begin()){
    Serial.println("player failed");
    stop();
  }
}

void loop() {
  player.copy();
  i2s.processActions();
}

We just need to connect to Wifi, define a FTPClient and a AudioSourceFTP that we can use to set up the AudioPlayer.

Dependencies

For this example you need to install the following libraries:

• TinyFTP library FTP Client Library
• Arduino Audio Tools Audio Library
• libhelix mp3 decoder
• Arduino Audio Driver for the AudioKit